** program ts1.prg
**
** note that output listing is defined here:
open output ts1.out

**************************************************************************
env batch
cal 54 1 4
all 0 93:4
**************************************************************************
*** note that you have to set the location of the allq.rat data set here
***
open data c:\allq.rat
data(format=rats) / emp2 ur2 upr2 lfp2 pall p1617 p1619 p2024 afp1619 $
                    kaitz kaitzw enr1619 enr1619b empm2554 rwage union $
                    minr cpi le6hm coverw coveru
close data
**************************************************************************
** emp = teenage emp-pop rate
** empm2554 = emp-pop rate for men age 25-54
** upr = unemployment rate
** pall = total population
** p1619 = teen population;  p1617= pop of 16+17 year olds
** p2024 = population of 20-24 year olds
** afp1619 = number of 16-19 year olds in armed forces 
** minr = real minimum wage (note error in 1990-I that is fixed below)
** cpi = cpi index
** le6hm = hourly wage in manufacturing (nominal)
** kaitzw= allison wellington Kaitz index
** kaitz = card/krueger Kaitz index for later years
** enr1619 = enrollment 16-19 year olds (later years)
** enr1619b = enrollment earlier years
** coverw = wellington coverage estimate
** coveru = update of coverage series

******create base variables
set empam = .001*empm2554
set pop = p1619/pall
set popa = p2024/pall
set sy = p1617/p1619
set afp = afp1619/p1619
set emp = .001*emp2
set upr = .001*upr2
set lwmanr = log(le6hm/cpi)
set wmanr = le6hm/(cpi*.01)

******combine AW's variables with ours
set enp 54:1 79:4 = enr1619b
set enp 80:1 93:4 = enr1619
set yk 54:1 86:4 = kaitzw
set yk 87:1 93:4 = kaitz
set cover 54:1 86:4 = coverw
set cover 87:1 93:4 = coveru

******create other variables
set trend = t
set trendsq = t**2
seasonal seasons

**take logs for basic models
set lyk = log(yk)
set lemp = log(emp)
set lempam = log(empam)
set lupr = log(upr)
set lpop = log(pop)
set lpopa = log(popa)
set lminr = log(minr)

** interactions of trend and seasonals
set tq2 = trend*seasons{-2}
set tq3 = trend*seasons{-1}
set tq4 = trend*seasons
set t2q2 = trendsq*seasons{-2}
set t2q3 = trendsq*seasons{-1}
set t2q4 = trendsq*seasons

***fix ups for error in minimum wage 1990-I 
***you must use yk2 as Kaitz index, lyk2 as log(Kaitz), minr2 as real min,
***and minchk2 as nominal minimum wage

set yk2 = yk
set yk2 90:01 90:01 = yk*3.35/3.25
set minr2 = minr
set minr2 90:01 90:01 = minr*3.35/3.25
set minchk = minr*cpi/144.4583
set minchk2 = minr2*cpi/144.4583
set lyk2 = log(yk2)
set lminr2 = log(minr2)
set lmin = log(minchk2)
 
table 54:1 72:4 emp yk2 cover upr sy afp pop empam
table 54:1 79:4 emp yk2 cover upr sy afp pop empam
table 54:1 86:4 emp yk2 cover upr sy afp pop empam
table 54:1 93:4 emp yk2 cover upr sy afp pop empam


print / minchk2 minr2 cover yk2 
print / emp empam upr sy afp


diff emp / demp
diff lemp / dlemp
diff sy / dsy
diff afp / dafp
diff lpop / dlpop
diff trend / dtrend 
diff trendsq / dtrendsq
diff seasons / dseasons
diff tq2 / dtq2
diff tq3 / dtq3
diff tq4 / dtq4
diff t2q2 / dt2q2
diff t2q3 / dt2q3 
diff t2q4 / dt2q4
diff yk2 / dyk2
diff lyk2 / dlyk2
diff lupr / dlupr
diff upr / dupr
diff empam / dempam
diff lempam / dlempam 
diff lminr2 / dlminr2
diff lmin / dlmin

***************************************************************************

*******Wellington's basic spec. log version
***ar(1) version 1954-79

ar1(method=maxl) lemp 54:1 79:4
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

***ar(1) version 1954-86

ar1(method=maxl) lemp 54:1 86:4
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

***ar(1) version all data
ar1(method=maxl) lemp
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

*** no ar(1) correction

linreg lemp
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0} $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

*** add emp-pop ratio of adult men

ar1(method=maxl) lemp
 #constant lyk2 lupr lempam sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

*** add emp-pop of adult men and log real wage in mfg

ar1(method=maxl) lemp
 #constant lyk2 lupr lempam lwmanr sy afp lpop trend trendsq seasons{-2 to 0} $
  tq2 tq3 tq4 t2q2 t2q3 t2q4 


****First-differenced log version (basic variable list)

linreg dlemp
 #constant dlyk2 dlupr dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} $
  dtq2 dtq3 dtq4 dt2q2 dt2q3 dt2q4


*******Wellington's basic spec. linear version
***ar(1) version

ar1(method=maxl) emp
 #constant yk2 upr sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

*** no ar(1) correction

linreg lemp
 #constant yk2 upr sy afp lpop trend trendsq seasons{-2 to 0} $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

*** add emp-pop rate of adult men

ar1(method=maxl) emp
 #constant yk2 empam upr sy afp pop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

****First-differenced levels 

linreg dlemp
 #constant dyk2 dupr dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} $
  dtq2 dtq3 dtq4 dt2q2 dt2q3 dt2q4


**** alternative methods for serial correlation (table 6.6)

**** MLE (grid search)

ar1(method=search) lemp
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

**** Corc
ar1(method=corc) lemp
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

**** hilu
ar1(method=hilu) lemp
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0}  $
  tq2 tq3 tq4 t2q2 t2q3 t2q4

*** differenced
linreg dlemp
 #constant dlyk2 dlupr dsy dafp dlpop dtrend dtrendsq  $
  dseasons{-2} dseasons{-1} dseasons dtq2 dtq3 dtq4 dt2q2 dt2q3 dt2q4

*** OLS, newey-white standard errors
linreg(robusterrors,lags=1,damp=1) lemp 
 #constant lyk2 lupr sy afp lpop trend trendsq seasons{-2 to 0} $
  tq2 tq3 tq4 t2q2 t2q3 t2q4



****First-differenced IV models (instrument = diff in real minimum wage)

instruments constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} $
  dtq2 dtq3 dtq4 dt2q2 dt2q3 dt2q4 dlupr dlminr2

linreg(inst) dlemp
 #constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} dtq2 dtq3 dtq4 $
  dt2q2 dt2q3 dt2q4 dlyk2 dlupr

****add adult male epop to list

instruments constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} $
  dtq2 dtq3 dtq4 dt2q2 dt2q3 dt2q4 dlupr dlempam dlminr2

linreg(inst) dlemp
 #constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} dtq2 dtq3 dtq4 $
  dt2q2 dt2q3 dt2q4 dlyk2 dlempam dlupr


****First-differenced IV models (instrument = diff in nominal minimum wage)

instruments constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} $
  dtq2 dtq3 dtq4 dt2q2 dt2q3 dt2q4 dlupr dlmin

linreg(inst) dlemp
 #constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} dtq2 dtq3 dtq4 $
  dt2q2 dt2q3 dt2q4 dlyk2 dlupr


****add adult male epop to list

instruments constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} $
  dtq2 dtq3 dtq4 dt2q2 dt2q3 dt2q4 dlupr dlempam dlmin

linreg(inst) dlemp
 #constant dsy dafp dlpop dtrend dtrendsq dseasons{-2 to 0} dtq2 dtq3 dtq4 $
  dt2q2 dt2q3 dt2q4 dlyk2 dlempam dlupr
end